<!--#include file="Conn.asp"--><%Checklogin("用户管理")%><!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html xmlns="http://www.w3.org/1999/xhtml">
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
<title>管理区域</title>
<link rel="stylesheet" href="css/common.css" type="text/css" />
<script language="javascript" src="js/jquery-1.7.2.min.js"></script>
<script type="text/javascript" src="js/js.js"></script>
<script>
function chkuserform(){
var id = document.getElementById("id").value,
_loginpwd = document.getElementById("usepwd"),
_loginpwd1 = document.getElementById("usepwd1"),
_save = document.getElementById("save");

if(_save.disabled)return false;

if( _loginpwd.value =='' && id =='' ){
alert('请输入用户密码');
_loginpwd.focus();
return false;
}
if( _loginpwd.value != _loginpwd1.value ){
alert('两次密码输入不相同');
_loginpwd1.focus();
return false;
}

_save.disabled = true;

}

</script>
</head>

<body>
<div id="man_zone">
<%
Act = Request.QueryString("act")
If act = "save" Then
isedit = False
id = Request.Form("id")
If id<>"" And IsNumeric(id) Then isedit = True
uselogin = TextEnCode(Request.Form("uselogin"))
usepwd = TextEnCode(Request.Form("usepwd"))
usename = TextEnCode(Request.Form("usename"))
usesex = TextEnCode(Request.Form("usesex"))
usecompany = TextEnCode(Request.Form("usecompany"))
usetel = TextEnCode(Request.Form("usetel"))
useemail = TextEnCode(Request.Form("useemail"))


If isedit Then
	If Conn.Execute("Select Count(id) From userinfo Where uselogin = '"&uselogin&"' And id<>"&id)(0)>0 Then Response.Write "<script>alert('Sorry，该用户已经存在，请检查更换');history.back()</script>":Conn.Close:Set Conn=Nothing:Response.End
	Set Rs = Server.CreateObject("ADODB.RecordSet")
	Rs.Open "Select uselogin,usepwd,usename,usesex,usecompany,usetel,useemail From userinfo Where id="&id,Conn,1,3
	If Not Rs.Bof And Not Rs.Eof Then
		Rs("uselogin")=uselogin
		If usepwd<>"" Then Rs("usepwd")=MD5(usepwd)
		Rs("usename")=usename
		Rs("usesex")=usesex
		Rs("usecompany")=usecompany
		Rs("usetel")=usetel
		Rs("useemail")=useemail
	Else
		'特殊情况不能添加
		Response.Write "<script>alert('Sorry，该用户已被删除，请重新添加');location.href='user.asp?act=add'</script>"
		Rs.Close:Set Rs=Nothing:Conn.Close:Set Conn=Nothing:Response.End
	End If
	Rs.Update:Rs.Close:Set Rs=Nothing:Conn.Close:Set Conn=Nothing
	Page = Request.QueryString("Page")
	Keys=Server.UrlEnCode(Request.QueryString("Keys"))
	Ord=Server.UrlEnCode(Request.QueryString("Ord"))
	Response.Redirect "?keys="&Keys&"&Ord="&Ord&"&Page="&Page
Else
	If Conn.Execute("Select Count(id) From userinfo Where uselogin = '"&uselogin&"'")(0)>0 Then Response.Write "<script>alert('Sorry，该用户已经存在，请检查更换');history.back()</script>":Conn.Close:Set Conn=Nothing:Response.End
	Conn.Execute("Insert into userinfo(uselogin,usepwd,usename,usesex,usecompany,usetel,useemail,state) values('"&uselogin&"','"&MD5(usepwd)&"','"&usename&"','"&usesex&"','"&usecompany&"','"&usetel&"','"&useemail&"',1)")
	Conn.Close:Set Conn=Nothing:Response.Redirect "?"
End If
Conn.Close:Set Conn=Nothing

Response.End
End If 'end save


If Act = "add" Or Act = "edit" Then
id = Request.QueryString("id")
isedit = False
If id<>"" And IsNumeric(id) Then isedit=True
If isedit Then
	Set Rs = Server.CreateObject("ADODB.RecordSet")
	Rs.Open "Select * From userinfo Where id="&id,Conn,1,1
	If Not Rs.Bof And Not Rs.Eof Then
		uselogin=Rs("uselogin"):usename=Rs("usename"):usesex=Rs("usesex"):usecompany=Rs("usecompany"):usetel=Rs("usetel"):useemail=Rs("useemail"):logincount=Rs("logincount"):logintime=Rs("logintime"):loginip=Rs("loginip")
	Else
		isedit = False
	End If
	Rs.Close:Set Rs=Nothing
End If

Page = Request.QueryString("Page")
Keys=Server.UrlEnCode(Request.QueryString("Keys"))
Ord=Server.UrlEnCode(Request.QueryString("Ord"))
hrefstr = "?keys="&Keys&"&Ord="&Ord&"&Page="&Page
%>
	<form name="form1" method="post" action="<%=hrefstr%>&act=save" onsubmit="return chkuserform()">
	<table width="100%" border="0" cellpadding="3" cellspacing="1" class="table1">
		<tbody>
			<tr>
				<th width="8%">用户帐号</th>
				<td><input type="text" id="uselogin" name="uselogin" value="<%=uselogin%>" class="txt1" /><input type="hidden" id="id" name="id" value="<%=id%>" /></td>
			</tr>
			<tr>
				<th width="8%">用户密码</th>
				<td><input type="password" id="usepwd" name="usepwd" class="txt1" /><%If isedit Then Response.Write "<span style=""color:red"">（不修改留空）</span>"%></td>
			</tr>
			<tr>
				<th width="8%">密码确认</th>
				<td><input type="password" id="usepwd1" name="usepwd1" class="txt1" /></td>
			</tr>
			<tr>
				<th width="8%">用户姓名</th>
				<td><input type="text" id="usename" name="usename" value="<%=usename%>" class="txt1" /></td>
			</tr>
			<tr>
				<th width="8%">性别</th>
				<td><label><input type="radio" name="usesex" value="先生"<%If usesex<>"女士" Then Response.Write " checked=""checked"""%> /> 先生</label>
 <label><input type="radio" name="usesex" value="女士"<%If usesex="女士" Then Response.Write " checked=""checked"""%> /> 女士</label></td>
			</tr>
			<tr>
				<th width="8%">公司名称</th>
				<td><input type="text" id="usecompany" name="usecompany" value="<%=usecompany%>" class="txt1" /></td>
			</tr>
			<tr>
				<th width="8%">电话</th>
				<td><input type="text" id="usetel" name="usetel" value="<%=usetel%>" class="txt1" /></td>
			</tr>
			<tr>
				<th width="8%">邮箱</th>
				<td><input type="text" id="useemail" name="useemail" value="<%=useemail%>" class="txt1" /></td>
			</tr>
<%
If isedit Then
%>
			<tr>
				<th width="8%">登陆时间</th>
				<td><input type="text" id="logintime" name="logintime" value="<%=logintime%>" disabled="disabled" class="txt1" /></td>
			</tr>
			<tr>
				<th width="8%">登陆IP</th>
				<td><input type="text" id="loginip" name="loginip" value="<%=loginip%>" disabled="disabled" class="txt1" /></td>
			</tr>
			<tr>
				<th width="8%">登陆次数</th>
				<td><input type="text" id="logincount" name="logincount" value="<%=logincount%>" disabled="disabled" class="txt1" /></td>
			</tr>
<%End If%>
			<tr>
				<th></th>
				<td><input type="submit" name="save" id="save" value="确定" class="btn1" /> <input type="reset" name="save" id="save" value="重置" class="btn1" /> <input type="button" value="返回" class="btn1" onClick="location.href='<%=hrefstr%>'" /></td>
			</tr>
		</tbody>
	</table>
	</form><%
If isedit Then

Set Rsu=Server.CreateObject("ADODB.RecordSet")
Rsu.Open "Select Top 20 * From useurl Where uid="&id&" Order By id Desc",Conn,1,1
If Not Rsu.Bof And Not Rsu.Eof Then
%>
	<div style="color:red">最近前20条访问页面</div>
	<table width="100%" border="0" cellpadding="3" cellspacing="1" class="table1">
		<thead>
			<tr>
				<th width="6%">序号</th>
				<th>Title</th>
				<th>URL</th>
				<th>Time</th>
				<th>IP</th>
			</tr>
		</thead>
		<tbody><%
	i=0
	Do While Not Rsu.Bof And Not Rsu.Eof
	i=i+1
%>
			<tr>
				<td><%=i%></td>
				<td><%=Rsu("wname")%></td>
				<td><a href="<%=Rsu("wurl")%>" target="_blank"><%=Rsu("wurl")%></a></td>
				<td><%=Rsu("addtime")%></td>
				<td><%=Rsu("addip")%></td>
			</tr><%

	Rsu.MoveNext
	Loop
%>
		</tbody>
	</table><%
End If 
Rsu.Close
Set Rsu=Nothing

End If
%>
</div>
</body>
</html>
<%
Response.End
End If 'End add


If Act="postchk" Then

Keys = Server.UrlEnCode(Request.QueryString("Keys"))
Ord = Server.UrlEnCode(Request.QueryString("Ord"))
Page = Request.QueryString("Page")
chkact = Request.Form("chkact")
SqlStr = ""
For i = 1 To Request.Form("chkbox").Count
	If SqlStr<>"" Then
		SqlStr = SqlStr & " Or id="&Request.Form("chkbox")(i)
	Else
		SqlStr = " Where id="&Request.Form("chkbox")(i)
	End If
Next

Select Case chkact
Case "0":SqlStr = "Update userinfo Set state="&chkact&SqlStr
Case "1":SqlStr = "Update userinfo Set state="&chkact&SqlStr
Case Else:SqlStr = "Delete From userinfo"&SqlStr
End Select

Conn.Execute(SqlStr):Conn.Close:Set Conn=Nothing
Response.Redirect "?Keys="&Keys&"&Ord="&Ord&"&Page="&Page
Response.End
End If	'End postchk


Keys=Request.QueryString("Keys")
Keyscode=TextEnCode(Keys)
Ord=Request.QueryString("Ord")
Page = Request.QueryString("Page")
If Ord="nstitle" Or Ord="nstitle Desc" Or Ord="nsaddtime" Or Ord="nsaddtime Desc" Or Ord="loginstate" Or Ord="loginstate Desc" Or Ord="nsord" Or Ord="nsord Desc" Then
	OrdStr=Ord&","
Else
	OrdStr=""
End If
Set Rs=Server.CreateObject("ADODB.RecordSet")
Rs.Open "Select * From userinfo Where uselogin like '%"&Keyscode&"%' Or usename like '%"&Keyscode&"%' Or usecompany like '%"&Keyscode&"%' Or usetel like '%"&Keyscode&"%' Or useemail like '%"&Keyscode&"%' Order By "&OrdStr&"Id Desc",Conn,1,1
Keys=Server.UrlEnCode(Keys)
Ord=Server.UrlEnCode(Ord)
hrefstr = "?keys="&Keys
%>	
	<form id="form1" method="post" action="?act=postchk&Keys=<%=keys%>&Ord=<%=Ord%>&Page=<%=Page%>" onSubmit="return false" />
	<table width="100%" border="0" cellpadding="3" cellspacing="1" class="table1">
		<thead>
			<tr>
				<th width="4%"><input type="checkbox" name="chkall" id="chkall" onClick="chkboxall(this,'chkbox')" /></th>
				<th width="6%">序号</th>
				<th width="12%">用户帐号</th>
				<th width="12%">用户姓名</th>
				<th width="12%">电话</th>
				<th width="12%">邮箱</th>
				<th width="20%">公司名称</th>
				<th width="8%">状态</th>
				<th width="10%">操作</th>
			</tr>
		</thead>
		<tbody>

<%
If Not Rs.Bof And Not Rs.Eof Then
	Rs.PageSize = 10
	If Page = "" Then Page = 1
	If Page = "end" Then Page = Rs.PageCount
	If Not IsNumeric(Page) Or Page < 1 Then Page = 1
	Page = Cint(Page)
	If Page > Rs.PageCount Then Page = Rs.PageCount
	Rs.AbsolutePage = Page
	TempNum = Rs.PageSize * (Page - 1)
	
	Set Rs1=Server.CreateObject("ADODB.RecordSet")

	For i=1 To Rs.PageSize
		If Rs.Bof Or Rs.Eof Then Exit For
		TempNum=TempNum+1
%>
			<tr onMouseOver="this.style.background='#F7FCFF'" onMouseOut="this.style.background='#FFFFFF'">
				<td align="center"><input type="checkbox" name="chkbox" value="<%=Rs(0)%>" /></td>
				<td align="center"><%=TempNum%></td>
				<td align="center"><%=Rs("uselogin")%></td>
				<td align="center"><%=Rs("usename")%></td>
				<td align="center"><%=Rs("usetel")%></td>
				<td align="center"><%=Rs("useemail")%></td>
				<td align="center"><%=Rs("usecompany")%></td>
				<td align="center"><%If Rs("state")=1 Then Response.Write "正常" Else Response.Write "<span style=""color:red"">停用</span>"%></td>
				<td align="center"><a href="?Keys=<%=keys%>&Ord=<%=Ord%>&Page=<%=Page%>&act=edit&id=<%=Rs(0)%>" class="ico_edit">修改</a></td>
			</tr>
<%
		Rs.MoveNext
	Next
Else
	If Keys="" Then
%>
			<tr>
				<td align="center" colspan="9">Sorry，当前暂无用户</td>
			</tr>

<%
	Else
%>
			<tr>
				<td align="center" colspan="9"><a href="?">Sorry，没有找到“<%=Keyscode%>”相关的用户，点击返回</a></td>
			</tr>
<%
	End If
End If
%>
		</tbody>
		<tfoot>
			<tr>
				<td colspan="9">
					<div class="showpagebox">
<%
If Rs.PageCount > 1 Then
	PageName="?Keys="&Keys&"&Ord="&Ord&"&"
	Pagelen=3
	If Page>1 Then
		Response.Write "<a href="""&PageName&"Page=1"">首页</a>"
		Response.Write "<a href="""&PageName&"Page="&Page-1&""">上一页</a>"
	End If

	If Pagelen*2+1 >= Rs.PageCount Then
		StartPage=1:EndPage=Rs.PageCount
	Else
		If Page<=Pagelen+1 Then
			StartPage=1
			EndPage=Pagelen*2+1
		Else
			StartPage=Page-Pagelen
			EndPage=Page+Pagelen
		End If
		If Page+Pagelen>Rs.PageCount Then StartPage=Rs.PageCount-Pagelen*2:EndPage=Rs.PageCount
	End If

	For i = StartPage To EndPage
		If i = Page Then
			Response.Write "<a class=""current"">"&i&"</a>"
		Else
			Response.Write "<a href="""&PageName&"Page="&i&""">"&i&"</a>"
		End If
	Next

	If Page<Rs.PageCount Then
		If Rs.PageCount - Page > Pagelen Then Response.Write "<a href="""&PageName&"Page="&Rs.PageCount&""">..."&Rs.PageCount&"</a>"
		Response.Write "<a href="""&PageName&"Page="&Page+1&""">下一页</a>"
		Response.Write "<a href="""&PageName&"Page="&Rs.PageCount&""">尾页</a>"
	End If

	Response.Write "<input type=""text"" id=""Pagego"" value="""&Page&""" onFocus=""if(this.value == '"&Page&"'){this.value='';}"" onBlur=""if(this.value == ''){this.value='"&Page&"';}"" onKeyUp=""this.value=this.value.replace(/\D/g,'')"" onKeyDown=""if(event.keyCode==13){location.href='"&PageName&"Page='+document.getElementById('Pagego').value}"" />"
End If
%>					</div>
					<div class="searchbox"><input type="text" id="keys" value="<%If Keyscode="" Then Response.Write "请输入搜索关键词" Else Response.Write Keyscode%>" onFocus="if(this.value == '<%If Keyscode="" Then Response.Write "请输入搜索关键词" Else Response.Write Keyscode%>'){this.value='';}" onBlur="if(this.value == ''){this.value='<%If Keyscode="" Then Response.Write "请输入搜索关键词" Else Response.Write Keyscode%>';}" onKeyDown="if(event.keyCode==13){location.href='?Keys='+escape(document.getElementById('keys').value)}" /><input type="button" id="searchgo" value="go" onClick="location.href='?Keys='+escape(document.getElementById('keys').value)" /></div>
					<div class="postchkbox">
						<select id="chkact" name="chkact">
							<option value="1">正常</option>
							<option value="0">停用</option>
							<option value="-1">删除</option>
						</select>
						<input type="button" value="执行" onClick="postchk(2)" class="btn1" />
					</div>
				</td>
			</tr>
		</tfoor>
	</table>
	</form>
<%Rs.Close:Set Rs=Nothing:Conn.Close:Set Conn=Nothing%>
</div>
</body>
</html>
